Find missing indexes for a database

* This script presents a list of missing indexes, based on the SQL DMV's.
* The script does take the database name as input parameter.
* This script complements the Database Engine Tuning Advisor. If you have identified a query
* that is expensive and this script doesn't have any suggestions, consider to use DTA
* since it still might be able to help.
* The "improvement_measure" column in this query's output is a rough indicator of the (estimated)
* improvement that might be seen if the index was created. This is a unitless number, and has
* meaning only relative the same number for other indexes. It's a combination of the
* avg_total_user_cost, avg_user_impact, user_seeks, and user_scans columns in
* sys.dm_db_missing_index_group_stats.
* The missing index DMVs don't make recommendation about whether a proposed index should be
* clustered or nonclustered. This has workload-wide ramifications, while these DMVs focus only on
* the indexes that would benefit individual queries. It won't consider partitioning.
* It's possible that the DMVs may not recommend the ideal column order for multi-column indexes.
* The DMV tracks information on no more than 500 missing indexes.
****************************************************************************************************************/

DECLARE @dbname sysname
DECLARE @dbid integer
SET @dbname = N'NULL'
SET @dbid = db_id(@dbname)

SELECT
mig.index_group_handle, mid.index_handle,
CONVERT (decimal (28,1),
migs.avg_total_user_cost * migs.avg_user_impact * (migs.user_seeks + migs.user_scans)
) AS improvement_measure,
'CREATE INDEX missing_index_' + CONVERT (varchar, mig.index_group_handle) + '_' + CONVERT (varchar, mid.index_handle)
+ ' ON ' + mid.statement
+ ' (' + ISNULL (mid.equality_columns,'')
+ CASE WHEN mid.equality_columns IS NOT NULL AND mid.inequality_columns IS NOT NULL THEN ',' ELSE '' END
+ ISNULL (mid.inequality_columns, '')
+ ')'
+ ISNULL (' INCLUDE (' + mid.included_columns + ')', '') AS create_index_statement,
migs.*, mid.database_id, mid.[object_id]
FROM sys.dm_db_missing_index_groups mig
INNER JOIN sys.dm_db_missing_index_group_stats migs ON migs.group_handle = mig.index_group_handle
INNER JOIN sys.dm_db_missing_index_details mid ON mig.index_handle = mid.index_handle
WHERE CONVERT (decimal (28,1), migs.avg_total_user_cost * migs.avg_user_impact * (migs.user_seeks + migs.user_scans)) > 10
AND database_id = @dbid
ORDER BY migs.avg_total_user_cost * migs.avg_user_impact * (migs.user_seeks + migs.user_scans) DESC